geometry_spherical.f90

Go to the documentation of this file.

!#############################################################################
!#                                                                           #
!# fosite - 3D hydrodynamical simulation program                             #
!# module: geometry_spherical.f90                                            #
!#                                                                           #
!# Copyright (C) 2007-2018                                                   #
!# Tobias Illenseer <tillense@astrophysik.uni-kiel.de>                       #
!# Manuel Jung                                                               #
!# Lars Bösch                                                                #
!# Jannes Klee <jklee@astrophysik.uni-kiel.de>                               #
!#                                                                           #
!# This program is free software; you can redistribute it and/or modify      #
!# it under the terms of the GNU General Public License as published by      #
!# the Free Software Foundation; either version 2 of the License, or (at     #
!# your option) any later version.                                           #
!#                                                                           #
!# This program is distributed in the hope that it will be useful, but       #
!# WITHOUT ANY WARRANTY; without even the implied warranty of                #
!# MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or        #
!# NON INFRINGEMENT.  See the GNU General Public License for more            #
!# details.                                                                  #
!#                                                                           #
!# You should have received a copy of the GNU General Public License         #
!# along with this program; if not, write to the Free Software               #
!# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.                 #
!#                                                                           #
!#############################################################################

!----------------------------------------------------------------------------!
!----------------------------------------------------------------------------!
MODULE geometry_spherical_mod
  USE geometry_base_mod
  USE marray_cellscalar_mod
  USE marray_cellvector_mod
  USE common_dict
  IMPLICIT NONE
  !--------------------------------------------------------------------------!
  TYPE, EXTENDS(geometry_base) :: geometry_spherical
  CONTAINS
    PROCEDURE :: initgeometry_spherical
    PROCEDURE :: scalefactors_1
    PROCEDURE :: scalefactors_2
    PROCEDURE :: scalefactors_3
    PROCEDURE :: scalefactors_4
    PROCEDURE :: radius_1
    PROCEDURE :: radius_2
    PROCEDURE :: radius_3
    PROCEDURE :: radius_4
    PROCEDURE :: positionvector_1
    PROCEDURE :: positionvector_2
    PROCEDURE :: positionvector_3
    PROCEDURE :: positionvector_4
    PROCEDURE :: convert2cartesian_coords_1
    PROCEDURE :: convert2cartesian_coords_2
    PROCEDURE :: convert2cartesian_coords_3
    PROCEDURE :: convert2cartesian_coords_4
    PROCEDURE :: convert2curvilinear_coords_1
    PROCEDURE :: convert2curvilinear_coords_2
    PROCEDURE :: convert2curvilinear_coords_3
    PROCEDURE :: convert2curvilinear_coords_4
    PROCEDURE :: convert2cartesian_vectors_1
    PROCEDURE :: convert2cartesian_vectors_2
    PROCEDURE :: convert2cartesian_vectors_3
    PROCEDURE :: convert2cartesian_vectors_4
    PROCEDURE :: convert2curvilinear_vectors_1
    PROCEDURE :: convert2curvilinear_vectors_2
    PROCEDURE :: convert2curvilinear_vectors_3
    PROCEDURE :: convert2curvilinear_vectors_4
    PROCEDURE :: finalize
  END TYPE
  PRIVATE
  CHARACTER(LEN=32), PARAMETER :: geometry_name = "spherical"
  !--------------------------------------------------------------------------!
  PUBLIC :: geometry_spherical
  !--------------------------------------------------------------------------!

CONTAINS

  SUBROUTINE initgeometry_spherical(this,config)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(INOUT) :: this
    TYPE(DICT_TYP),POINTER                   :: config
    !------------------------------------------------------------------------!
    CALL this%InitGeometry(spherical,geometry_name,config)
    CALL this%SetAzimuthIndex(3)
  END SUBROUTINE initgeometry_spherical

  PURE SUBROUTINE scalefactors_1(this,coords,hx,hy,hz)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, INTENT(IN),  DIMENSION(:,:) :: coords
    REAL, INTENT(OUT), DIMENSION(:)   :: hx,hy,hz
    !------------------------------------------------------------------------!
    CALL scalefactors(coords(:,1),coords(:,2),hx(:),hy(:),hz(:))
  END SUBROUTINE scalefactors_1

  PURE SUBROUTINE scalefactors_2(this,coords,hx,hy,hz)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, INTENT(IN),  DIMENSION(:,:,:) :: coords
    REAL, INTENT(OUT), DIMENSION(:,:)   :: hx,hy,hz
    !------------------------------------------------------------------------!
    CALL scalefactors(coords(:,:,1),coords(:,:,2),hx(:,:),hy(:,:),hz(:,:))
  END SUBROUTINE scalefactors_2

  PURE SUBROUTINE scalefactors_3(this,coords,hx,hy,hz)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, INTENT(IN),  DIMENSION(:,:,:,:) :: coords
    REAL, INTENT(OUT), DIMENSION(:,:,:)   :: hx,hy,hz
    !------------------------------------------------------------------------!
    CALL scalefactors(coords(:,:,:,1),coords(:,:,:,2),hx(:,:,:), &
                      hy(:,:,:),hz(:,:,:))
  END SUBROUTINE scalefactors_3

  PURE SUBROUTINE scalefactors_4(this,coords,hx,hy,hz)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, INTENT(IN),  DIMENSION(:,:,:,:,:) :: coords
    REAL, INTENT(OUT), DIMENSION(:,:,:,:)   :: hx,hy,hz
    !------------------------------------------------------------------------!
    CALL scalefactors(coords(:,:,:,:,1),coords(:,:,:,:,2),hx(:,:,:,:), &
                      hy(:,:,:,:),hz(:,:,:,:))
  END SUBROUTINE scalefactors_4

  PURE SUBROUTINE radius_1(this,coords,r)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:), INTENT(IN) :: coords
    REAL, DIMENSION(:),  INTENT(OUT) :: r
    !------------------------------------------------------------------------!
    r = radius(coords(:,1))
  END SUBROUTINE radius_1

  PURE SUBROUTINE radius_2(this,coords,r)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:), INTENT(IN) :: coords
    REAL, DIMENSION(:,:),  INTENT(OUT) :: r
    !------------------------------------------------------------------------!
    r = radius(coords(:,:,1))
  END SUBROUTINE radius_2

  PURE SUBROUTINE radius_3(this,coords,r)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:), INTENT(IN) :: coords
    REAL, DIMENSION(:,:,:),  INTENT(OUT) :: r
    !------------------------------------------------------------------------!
    r = radius(coords(:,:,:,1))
  END SUBROUTINE radius_3

  PURE SUBROUTINE radius_4(this,coords,r)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN) :: coords
    REAL, DIMENSION(:,:,:,:),  INTENT(OUT) :: r
    !------------------------------------------------------------------------!
    r = radius(coords(:,:,:,:,1))
  END SUBROUTINE radius_4

  PURE SUBROUTINE positionvector_1(this,coords,posvec)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN)  :: this
    REAL, DIMENSION(:,:), INTENT(IN)  :: coords
    REAL, DIMENSION(:,:), INTENT(OUT) :: posvec
    !------------------------------------------------------------------------!
    CALL positionvector(coords(:,1),posvec(:,1),posvec(:,2),posvec(:,3))
  END SUBROUTINE positionvector_1

  PURE SUBROUTINE positionvector_2(this,coords,posvec)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN)  :: this
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: coords
    REAL, DIMENSION(:,:,:), INTENT(OUT) :: posvec
    !------------------------------------------------------------------------!
    CALL positionvector(coords(:,:,1),posvec(:,:,1),posvec(:,:,2),posvec(:,:,3))
  END SUBROUTINE positionvector_2

  PURE SUBROUTINE positionvector_3(this,coords,posvec)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN)  :: this
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: coords
    REAL, DIMENSION(:,:,:,:), INTENT(OUT) :: posvec
    !------------------------------------------------------------------------!
    CALL positionvector(coords(:,:,:,1),posvec(:,:,:,1), &
                        posvec(:,:,:,2),posvec(:,:,:,3))
  END SUBROUTINE positionvector_3

  PURE SUBROUTINE positionvector_4(this,coords,posvec)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN)  :: this
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: coords
    REAL, DIMENSION(:,:,:,:,:), INTENT(OUT) :: posvec
    !------------------------------------------------------------------------!
    CALL positionvector(coords(:,:,:,:,1),posvec(:,:,:,:,1), &
                        posvec(:,:,:,:,2),posvec(:,:,:,:,3))
  END SUBROUTINE positionvector_4

  PURE SUBROUTINE convert2cartesian_coords_1(this,curv,cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:), INTENT(OUT) :: cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_coords(curv(:,1),curv(:,2),curv(:,3), &
                                  cart(:,1),cart(:,2),cart(:,3))
  END SUBROUTINE convert2cartesian_coords_1

  PURE SUBROUTINE convert2cartesian_coords_2(this,curv,cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:), INTENT(OUT) :: cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_coords(curv(:,:,1),curv(:,:,2),curv(:,:,3), &
                                  cart(:,:,1),cart(:,:,2),cart(:,:,3))
  END SUBROUTINE convert2cartesian_coords_2

  PURE SUBROUTINE convert2cartesian_coords_3(this,curv,cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:,:), INTENT(OUT) :: cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_coords(curv(:,:,:,1),curv(:,:,:,2),curv(:,:,:,3), &
                                  cart(:,:,:,1),cart(:,:,:,2),cart(:,:,:,3))
  END SUBROUTINE convert2cartesian_coords_3

  PURE SUBROUTINE convert2cartesian_coords_4(this,curv,cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:,:,:), INTENT(OUT) :: cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_coords(curv(:,:,:,:,1),curv(:,:,:,:,2),curv(:,:,:,:,3), &
                                  cart(:,:,:,:,1),cart(:,:,:,:,2),cart(:,:,:,:,3))
  END SUBROUTINE convert2cartesian_coords_4

  PURE SUBROUTINE convert2curvilinear_coords_1(this,cart,curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:), INTENT(IN)  :: cart
    REAL, DIMENSION(:,:), INTENT(OUT) :: curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_coords(cart(:,1),cart(:,2),cart(:,3), &
                                    curv(:,1),curv(:,2),curv(:,3))
  END SUBROUTINE convert2curvilinear_coords_1

  PURE SUBROUTINE convert2curvilinear_coords_2(this,cart,curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: cart
    REAL, DIMENSION(:,:,:), INTENT(OUT) :: curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_coords(cart(:,:,1),cart(:,:,2),cart(:,:,3), &
                                    curv(:,:,1),curv(:,:,2),curv(:,:,3))
  END SUBROUTINE convert2curvilinear_coords_2

  PURE SUBROUTINE convert2curvilinear_coords_3(this,cart,curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: cart
    REAL, DIMENSION(:,:,:,:), INTENT(OUT) :: curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_coords(cart(:,:,:,1),cart(:,:,:,2),cart(:,:,:,3), &
                                    curv(:,:,:,1),curv(:,:,:,2),curv(:,:,:,3))
  END SUBROUTINE convert2curvilinear_coords_3

  PURE SUBROUTINE convert2curvilinear_coords_4(this,cart,curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: cart
    REAL, DIMENSION(:,:,:,:,:), INTENT(OUT) :: curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_coords(cart(:,:,:,:,1),cart(:,:,:,:,2),cart(:,:,:,:,3), &
                                    curv(:,:,:,:,1),curv(:,:,:,:,2),curv(:,:,:,:,3))
  END SUBROUTINE convert2curvilinear_coords_4

  PURE SUBROUTINE convert2cartesian_vectors_1(this,curv,v_curv,v_cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:), INTENT(IN)  :: v_curv
    REAL, DIMENSION(:,:), INTENT(OUT) :: v_cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_vectors(curv(:,1),curv(:,2),curv(:,3), &
                                  v_curv(:,1),v_curv(:,2),v_curv(:,3), &
                                  v_cart(:,1),v_cart(:,2),v_cart(:,3))
  END SUBROUTINE convert2cartesian_vectors_1

  PURE SUBROUTINE convert2cartesian_vectors_2(this,curv,v_curv,v_cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: v_curv
    REAL, DIMENSION(:,:,:), INTENT(OUT) :: v_cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_vectors(curv(:,:,1),curv(:,:,2),curv(:,:,3), &
                                  v_curv(:,:,1),v_curv(:,:,2),v_curv(:,:,3), &
                                  v_cart(:,:,1),v_cart(:,:,2),v_cart(:,:,3))
  END SUBROUTINE convert2cartesian_vectors_2

  PURE SUBROUTINE convert2cartesian_vectors_3(this,curv,v_curv,v_cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: v_curv
    REAL, DIMENSION(:,:,:,:), INTENT(OUT) :: v_cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_vectors(curv(:,:,:,1),curv(:,:,:,2),curv(:,:,:,3), &
                                  v_curv(:,:,:,1),v_curv(:,:,:,2),v_curv(:,:,:,3), &
                                  v_cart(:,:,:,1),v_cart(:,:,:,2),v_cart(:,:,:,3))
  END SUBROUTINE convert2cartesian_vectors_3

  PURE SUBROUTINE convert2cartesian_vectors_4(this,curv,v_curv,v_cart)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: v_curv
    REAL, DIMENSION(:,:,:,:,:), INTENT(OUT) :: v_cart
    !------------------------------------------------------------------------!
    CALL convert2cartesian_vectors(curv(:,:,:,:,1),curv(:,:,:,:,2),curv(:,:,:,:,3), &
                                  v_curv(:,:,:,:,1),v_curv(:,:,:,:,2),v_curv(:,:,:,:,3), &
                                  v_cart(:,:,:,:,1),v_cart(:,:,:,:,2),v_cart(:,:,:,:,3))
  END SUBROUTINE convert2cartesian_vectors_4

  PURE SUBROUTINE convert2curvilinear_vectors_1(this,curv,v_cart,v_curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:), INTENT(IN)  :: v_cart
    REAL, DIMENSION(:,:), INTENT(OUT) :: v_curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_vectors(curv(:,1),curv(:,2),curv(:,3), &
                                  v_cart(:,1),v_cart(:,2),v_cart(:,3), &
                                  v_curv(:,1),v_curv(:,2),v_curv(:,3))
  END SUBROUTINE convert2curvilinear_vectors_1

  PURE SUBROUTINE convert2curvilinear_vectors_2(this,curv,v_cart,v_curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:), INTENT(IN)  :: v_cart
    REAL, DIMENSION(:,:,:), INTENT(OUT) :: v_curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_vectors(curv(:,:,1),curv(:,:,2),curv(:,:,3), &
                                  v_cart(:,:,1),v_cart(:,:,2),v_cart(:,:,3), &
                                  v_curv(:,:,1),v_curv(:,:,2),v_curv(:,:,3))
  END SUBROUTINE convert2curvilinear_vectors_2

  PURE SUBROUTINE convert2curvilinear_vectors_3(this,curv,v_cart,v_curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:,:), INTENT(IN)  :: v_cart
    REAL, DIMENSION(:,:,:,:), INTENT(OUT) :: v_curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_vectors(curv(:,:,:,1),curv(:,:,:,2),curv(:,:,:,3), &
                                  v_cart(:,:,:,1),v_cart(:,:,:,2),v_cart(:,:,:,3), &
                                  v_curv(:,:,:,1),v_curv(:,:,:,2),v_curv(:,:,:,3))
  END SUBROUTINE convert2curvilinear_vectors_3

  PURE SUBROUTINE convert2curvilinear_vectors_4(this,curv,v_cart,v_curv)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(IN) :: this
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: curv
    REAL, DIMENSION(:,:,:,:,:), INTENT(IN)  :: v_cart
    REAL, DIMENSION(:,:,:,:,:), INTENT(OUT) :: v_curv
    !------------------------------------------------------------------------!
    CALL convert2curvilinear_vectors(curv(:,:,:,:,1),curv(:,:,:,:,2),curv(:,:,:,:,3), &
                                  v_cart(:,:,:,:,1),v_cart(:,:,:,:,2),v_cart(:,:,:,:,3), &
                                  v_curv(:,:,:,:,1),v_curv(:,:,:,:,2),v_curv(:,:,:,:,3))
  END SUBROUTINE convert2curvilinear_vectors_4

  SUBROUTINE finalize(this)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(geometry_spherical), INTENT(INOUT) :: this
    !------------------------------------------------------------------------!
    CALL this%Finalize_base()
  END SUBROUTINE finalize

  ELEMENTAL SUBROUTINE scalefactors(r,theta,hr,htheta,hphi)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)  :: r,theta
    REAL, INTENT(OUT) :: hr,htheta,hphi
    !------------------------------------------------------------------------!
    hr     = 1.
    htheta = r
    hphi   = r * sin(theta)
  END SUBROUTINE scalefactors

  ELEMENTAL FUNCTION radius(r)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)  :: r
    REAL :: radius
    !------------------------------------------------------------------------!
    radius = r
  END FUNCTION radius

  ELEMENTAL SUBROUTINE positionvector(r,rx,ry,rz)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)  :: r
    REAL, INTENT(OUT) :: rx,ry,rz
    !------------------------------------------------------------------------!
    rx = r
    ry = 0.0
    rz = 0.0
  END SUBROUTINE positionvector

  ELEMENTAL SUBROUTINE convert2cartesian_coords(r,theta,phi,x,y,z)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)  :: r,theta,phi
    REAL, INTENT(OUT) :: x,y,z
    !------------------------------------------------------------------------!
    x = r*sin(theta)*cos(phi)
    y = r*sin(theta)*sin(phi)
    z = r*cos(theta)
  END SUBROUTINE convert2cartesian_coords

  ELEMENTAL SUBROUTINE convert2curvilinear_coords(x,y,z,r,theta,phi)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)  :: x,y,z
    REAL, INTENT(OUT) :: r,theta,phi
    !------------------------------------------------------------------------!
    r = sqrt(x*x+y*y+z*z)
    theta = acos(z/r)
    phi = atan2(y,x)
    IF (phi.LT.0.0) THEN
      phi = phi + 2.0*pi
    END IF
  END SUBROUTINE convert2curvilinear_coords

  ELEMENTAL SUBROUTINE convert2cartesian_vectors(r,theta,phi,vr,vtheta,vphi,vx,vy,vz)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)                      :: r,theta,phi,vr,vtheta,vphi
    REAL, INTENT(OUT)                     :: vx,vy,vz
    !------------------------------------------------------------------------!
    vx = vr*sin(theta)*cos(phi) + vtheta*cos(theta)*cos(phi) - vphi*sin(phi)
    vy = vr*sin(theta)*sin(phi) + vtheta*cos(theta)*sin(phi) + vphi*cos(phi)
    vz = vr*cos(theta) - vtheta*sin(theta)
  END SUBROUTINE convert2cartesian_vectors

  ELEMENTAL SUBROUTINE convert2curvilinear_vectors(r,theta,phi,vx,vy,vz,vr,vtheta,vphi)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    REAL, INTENT(IN)                      :: r,theta,phi,vx,vy,vz
    REAL, INTENT(OUT)                     :: vr,vtheta,vphi
    !------------------------------------------------------------------------!
    vr     = vx*sin(theta)*cos(phi) + vy*sin(theta)*sin(phi) + vz*cos(theta)
    vtheta = vx*cos(theta)*cos(phi) + vy*cos(theta)*sin(phi) - vz*sin(theta)
    vphi   = -vx*sin(phi) + vy*cos(phi)
  END SUBROUTINE convert2curvilinear_vectors

END MODULE geometry_spherical_mod