riemann3d.f90

Go to the documentation of this file.

!#############################################################################
!#                                                                           #
!# fosite - 3D hydrodynamical simulation program                             #
!# module: riemann3d.f90                                                     #
!#                                                                           #
!# Copyright (C) 2006-2018                                                   #
!# Tobias Illenseer <tillense@astrophysik.uni-kiel.de>                       #
!#                                                                           #
!# This program is free software; you can redistribute it and/or modify      #
!# it under the terms of the GNU General Public License as published by      #
!# the Free Software Foundation; either version 2 of the License, or (at     #
!# your option) any later version.                                           #
!#                                                                           #
!# This program is distributed in the hope that it will be useful, but       #
!# WITHOUT ANY WARRANTY; without even the implied warranty of                #
!# MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or        #
!# NON INFRINGEMENT.  See the GNU General Public License for more            #
!# details.                                                                  #
!#                                                                           #
!# You should have received a copy of the GNU General Public License         #
!# along with this program; if not, write to the Free Software               #
!# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.                 #
!#                                                                           #
!#############################################################################

!----------------------------------------------------------------------------!
!----------------------------------------------------------------------------!
PROGRAM riemann3d
  USE fosite_mod
#include "tap.h"
  IMPLICIT NONE
  !--------------------------------------------------------------------------!
  ! simulation parameters
  REAL, PARAMETER    :: tsim  = 0.7        ! simulation time
  REAL, PARAMETER    :: gamma = 1.4        ! ratio of specific heats
  ! mesh settings
  INTEGER, PARAMETER :: mgeo = cylindrical ! geometry
  INTEGER, PARAMETER :: xres  = 150        ! x-resolution
  INTEGER, PARAMETER :: yres  = 1         ! y-resolution
  INTEGER, PARAMETER :: zres  = 100        ! y-resolution
  ! output parameters
  INTEGER, PARAMETER :: onum = 7           ! number of output data sets
  CHARACTER(LEN=256), PARAMETER &          ! output data dir
                     :: odir = './'
  CHARACTER(LEN=256), PARAMETER &          ! output data file name
                     :: ofname = 'riemann3d'
  !--------------------------------------------------------------------------!
  CLASS(fosite), ALLOCATABLE   :: sim
  LOGICAL :: ok
  !--------------------------------------------------------------------------!

  tap_plan(1)

  ALLOCATE(sim)
  CALL sim%InitFosite()
  CALL makeconfig(sim, sim%config)
  CALL sim%Setup()
  CALL initdata(sim%Mesh, sim%Physics, sim%Timedisc)

  CALL sim%Run()
  ok = .NOT.sim%aborted
  CALL sim%Finalize()
  DEALLOCATE(sim)

  tap_check(ok,"stoptime reached")
  tap_done

CONTAINS

  SUBROUTINE makeconfig(Sim, config)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(fosite)           :: Sim
    TYPE(Dict_TYP),POINTER  :: config
    !------------------------------------------------------------------------!
    ! Local variable declaration
    REAL              :: z0,z1,r0,r1
    TYPE(Dict_TYP), POINTER :: mesh, physics, boundary, datafile, logfile, &
                               timedisc, fluxes
    REAL              :: x1,x2,y1,y2
    !------------------------------------------------------------------------!
    INTENT(INOUT)     :: sim
    !------------------------------------------------------------------------!

    ! mesh settings
    mesh => dict("meshtype" / midpoint, &
           "geometry" / cylindrical, &
               "inum" / xres, &
               "jnum" / yres, &
               "knum" / zres, &
               "xmin" / 0.0, &
               "xmax" / 1.5, &
               "ymin" / (-pi), &
               "ymax" / pi, &
               "zmin" / 0.0, &
               "zmax" / 1.0, &
             "gparam" / 1.0)

    ! physics settings
    physics => dict("problem" / euler, &
              "gamma"   / 1.4, &           ! ratio of specific heats        !
              "mu"      / 0.029)         ! mean molecular weight          !

    ! flux calculation and reconstruction method
    fluxes => dict("order"     / linear, &
             "fluxtype"  / kt, &
             "variables" / conservative, &        ! vars. to use for reconstruction!
             "limiter"   / monocent, &    ! one of: minmod, monocent,...   !
             "theta"     / 1.2)          ! optional parameter for limiter !

    ! boundary conditions
    boundary => dict(&
               "western"  / axis, &
               "eastern"  / reflecting, &
               "southern" / periodic, &
               "northern" / periodic, &
               "bottomer" / reflecting, &
               "topper"   / reflecting)

   ! time discretization settings
   timedisc => dict("method"   / modified_euler, &
              "order"    / 3, &
              "cfl"      / 0.4, &
              "stoptime" / tsim, &
              "dtlimit"  / 1.0e-9, &
              "maxiter"  / 1000000)

    ! initialize data input/output
    datafile => dict( &
            "fileformat" / vtk, &
            "filename"   / (trim(odir) // trim(ofname)), &
            "count"      / onum)


    config => dict("mesh" / mesh, &
             "physics"  / physics, &
             "boundary" / boundary, &
             "fluxes"   / fluxes, &
             "timedisc" / timedisc, &
!             "logfile"  / logfile, &
             "datafile" / datafile)
  END SUBROUTINE makeconfig


  SUBROUTINE initdata(Mesh,Physics,Timedisc)
    USE geometry_base_mod
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(physics_base)         :: Physics
    CLASS(mesh_base)            :: Mesh
    CLASS(timedisc_base)        :: Timedisc
    !------------------------------------------------------------------------!
    ! Local variable declaration
    REAL              :: rmax,x0,y0,z0
    REAL              :: P_in, P_out
    !------------------------------------------------------------------------!
    INTENT(IN)        :: mesh,physics
    INTENT(INOUT)     :: timedisc
    !------------------------------------------------------------------------!
    ! radius and cartesian position of the bubble
    rmax = 0.2
    x0 = 0.0
    y0 = 0.0
    z0 = 0.4
    
    ! inside and ambient pressure
    p_in  = 5.0
    p_out = 1.0

    ! initial condition
    SELECT TYPE(pvar => timedisc%pvar)
    TYPE IS(statevector_euler) ! non-isothermal HD
      ! constant density
      pvar%density%data1d(:)  = 1.0
      ! vanishing velocities
      pvar%velocity%data1d(:) = 0.0
      ! pressure pulse
      WHERE (((mesh%bccart(:,:,:,1)-x0)**2+(mesh%bccart(:,:,:,2)-y0)**2 &
             +(mesh%bccart(:,:,:,3)-z0)**2).LT.rmax**2)
        pvar%pressure%data3d(:,:,:) = p_in
      ELSEWHERE
        pvar%pressure%data3d(:,:,:) = p_out
      END WHERE
    CLASS DEFAULT
      CALL physics%Error("riemann3d::InitData","physics not supported")
    END SELECT

    CALL physics%Convert2Conservative(timedisc%pvar,timedisc%cvar)

    CALL physics%Info(" DATA-----> initial condition: Spherical pressure discontinuity between walls")
  END SUBROUTINE initdata

END PROGRAM riemann3d