boundary_nogradients.f90

Go to the documentation of this file.

!#############################################################################
!#                                                                           #
!# fosite - 3D hydrodynamical simulation program                             #
!# module: boundary_nogradients.f90                                          #
!#                                                                           #
!# Copyright (C) 2006-2017                                                   #
!# Tobias Illenseer <tillense@astrophysik.uni-kiel.de>                       #
!# Jannes Klee      <jklee@astrophysik.uni-kiel.de>                          #
!#                                                                           #
!# This program is free software; you can redistribute it and/or modify      #
!# it under the terms of the GNU General Public License as published by      #
!# the Free Software Foundation; either version 2 of the License, or (at     #
!# your option) any later version.                                           #
!#                                                                           #
!# This program is distributed in the hope that it will be useful, but       #
!# WITHOUT ANY WARRANTY; without even the implied warranty of                #
!# MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or        #
!# NON INFRINGEMENT.  See the GNU General Public License for more            #
!# details.                                                                  #
!#                                                                           #
!# You should have received a copy of the GNU General Public License         #
!# along with this program; if not, write to the Free Software               #
!# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.                 #
!#                                                                           #
!#############################################################################

!----------------------------------------------------------------------------!
!----------------------------------------------------------------------------!
MODULE boundary_nogradients_mod
  USE boundary_base_mod
  USE marray_compound_mod
  USE mesh_base_mod
  USE physics_base_mod
  USE common_dict
  IMPLICIT NONE
  !--------------------------------------------------------------------------!
  PRIVATE
  TYPE, EXTENDS(boundary_base) :: boundary_nogradients
  CONTAINS
    PROCEDURE :: initboundary_nogradients
    PROCEDURE :: setboundarydata
    PROCEDURE :: finalize
  END TYPE boundary_nogradients
  CHARACTER(LEN=32), PARAMETER  :: boundcond_name = "nogradients"
  !--------------------------------------------------------------------------!
  PUBLIC :: &
       ! types
       boundary_nogradients
  !--------------------------------------------------------------------------!

CONTAINS

  SUBROUTINE initboundary_nogradients(this,Mesh,Physics,dir,config)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(boundary_nogradients), INTENT(INOUT) :: this
    CLASS(physics_base), INTENT(IN)            :: Physics
    CLASS(mesh_base), INTENT(IN)               :: Mesh
    TYPE(Dict_TYP), POINTER                    :: config
    INTEGER                                    :: dir
    !------------------------------------------------------------------------!
    INTENT(IN)                                 :: dir
    !------------------------------------------------------------------------!
    CALL this%InitBoundary(mesh,physics,no_gradients,boundcond_name,dir,config)
  END SUBROUTINE initboundary_nogradients

  PURE SUBROUTINE setboundarydata(this,Mesh,Physics,time,pvar)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(boundary_nogradients), INTENT(INOUT) :: this
    CLASS(mesh_base), INTENT(IN)            :: mesh
    CLASS(physics_base), INTENT(IN)         :: physics
    REAL,                 INTENT(IN)        :: time
    CLASS(marray_compound), INTENT(INOUT)   :: pvar
    !------------------------------------------------------------------------!
    INTEGER                                 :: i,j,k
    !------------------------------------------------------------------------!
    SELECT CASE(this%direction%GetType())
    CASE(west)
       ! UNROLL=Mesh%GNUM would be sufficient, but the compiler does
       ! not know the value of Mesh%GNUM, hence we set UNROLL=4 and
       ! hope that nobody sets Mesh%GNUM to a value greater than 4
!NEC$ UNROLL(4)
       DO i=1,mesh%GINUM
          pvar%data4d(mesh%IMIN-i,mesh%JMIN:mesh%JMAX,mesh%KMIN:mesh%KMAX,:) = &
            pvar%data4d(mesh%IMIN,mesh%JMIN:mesh%JMAX,mesh%KMIN:mesh%KMAX,:)
       END DO
    CASE(east)
!NEC$ UNROLL(4)
       DO i=1,mesh%GINUM
          pvar%data4d(mesh%IMAX+i,mesh%JMIN:mesh%JMAX,mesh%KMIN:mesh%KMAX,:) = &
            pvar%data4d(mesh%IMAX,mesh%JMIN:mesh%JMAX,mesh%KMIN:mesh%KMAX,:)
       END DO
    CASE(south)
!NEC$ UNROLL(4)
       DO j=1,mesh%GJNUM
          pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMIN-j,mesh%KMIN:mesh%KMAX,:) = &
            pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMIN,mesh%KMIN:mesh%KMAX,:)
       END DO
    CASE(north)
!NEC$ UNROLL(4)
       DO j=1,mesh%GJNUM
          pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMAX+j,mesh%KMIN:mesh%KMAX,:) = &
            pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMAX,mesh%KMIN:mesh%KMAX,:)
       END DO
    CASE(bottom)
!NEC$ UNROLL(4)
       DO k=1,mesh%GKNUM
          pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMIN:mesh%JMAX,mesh%KMIN-k,:) = &
            pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMIN:mesh%JMAX,mesh%KMIN,:)
       END DO
    CASE(top)
!NEC$ UNROLL(4)
       DO k=1,mesh%GKNUM
          pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMIN:mesh%JMAX,mesh%KMAX+k,:) = &
            pvar%data4d(mesh%IMIN:mesh%IMAX,mesh%JMIN:mesh%JMAX,mesh%KMAX,:)
       END DO
    END SELECT

  END SUBROUTINE setboundarydata

  SUBROUTINE finalize(this)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(boundary_nogradients), INTENT(INOUT) :: this
    !------------------------------------------------------------------------!
    CALL this%Finalize_base()
  END SUBROUTINE finalize

END MODULE boundary_nogradients_mod