gravity_generic.f90

Go to the documentation of this file.

!#############################################################################
!#                                                                           #
!# fosite - 3D hydrodynamical simulation program                             #
!# module: gravity_generic.f90                                               #
!#                                                                           #
!# Copyright (C) 2016-2018                                                   #
!# Manuel Jung <mjung@astrophysik.uni-kiel.de>                               #
!# Jannes Klee <jklee@astrophysik.uni-kiel.de>                               #
!#                                                                           #
!# This program is free software; you can redistribute it and/or modify      #
!# it under the terms of the GNU General Public License as published by      #
!# the Free Software Foundation; either version 2 of the License, or (at     #
!# your option) any later version.                                           #
!#                                                                           #
!# This program is distributed in the hope that it will be useful, but       #
!# WITHOUT ANY WARRANTY; without even the implied warranty of                #
!# MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or        #
!# NON INFRINGEMENT.  See the GNU General Public License for more            #
!# details.                                                                  #
!#                                                                           #
!# You should have received a copy of the GNU General Public License         #
!# along with this program; if not, write to the Free Software               #
!# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.                 #
!#                                                                           #
!#############################################################################
!----------------------------------------------------------------------------!
!! \author Jannes Klee
!!
!! \brief constructor for gravity class
!!
!! This module allocates the gravity class and decides which specific
!! source to use from the config.
!----------------------------------------------------------------------------!
MODULE gravity_generic_mod
  USE gravity_base_mod
  USE gravity_binary_mod
  USE gravity_pointmass_mod
  USE gravity_sboxspectral_mod
  USE gravity_spectral_mod
  USE mesh_base_mod
  USE fluxes_base_mod
  USE physics_base_mod
  USE common_dict

CONTAINS

  SUBROUTINE new_gravity(this,Mesh,Fluxes,Physics,config,IO)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(gravity_base), POINTER :: this
    CLASS(mesh_base)             :: Mesh
    CLASS(fluxes_base)           :: Fluxes
    CLASS(physics_base)          :: Physics
    TYPE(DICT_TYP),      POINTER :: config, IO
    !------------------------------------------------------------------------!
    CLASS(gravity_base), POINTER :: newgrav, tmpgrav
    TYPE(Dict_TYP),      POINTER :: dir,grav,IOgrav
    INTEGER                      :: gtype
    !------------------------------------------------------------------------!
    dir => config
    DO WHILE(ASSOCIATED(dir))
      NULLIFY(iograv)
      IF (haschild(dir) .AND. (trim(getkey(dir)).NE."output")) THEN
        grav => getchild(dir)
        CALL getattr(grav, "gtype", gtype)

        ! object creation
        SELECT CASE(gtype)
        CASE(pointmass)
          ALLOCATE(gravity_pointmass::newgrav)
        CASE(pointmass_binary)
          ALLOCATE(gravity_binary::newgrav)
        CASE(sboxspectral)
          ALLOCATE(gravity_sboxspectral::newgrav)
        CASE(spectral)
          ALLOCATE(gravity_spectral::newgrav)
        CASE DEFAULT
          CALL this%Error("new_gravity","Unknown gravity type")
        END SELECT

        IF (.NOT.ASSOCIATED(this)) THEN
          this => newgrav
          NULLIFY(this%next)
        ELSE
          tmpgrav => this
          this => newgrav
          this%next => tmpgrav
        END IF

        SELECT TYPE(obj => newgrav)
        TYPE IS (gravity_pointmass)
           ! gravitational acceleration due to point mass
           CALL obj%InitGravity_pointmass(mesh,physics,grav,iograv)
        TYPE IS (gravity_binary)
           ! gravitational acceleration due to two circling point masses
           CALL obj%InitGravity_binary(mesh,physics,grav,iograv)
        TYPE IS (gravity_sboxspectral)
           ! self-gravitation in flat geometries periodic in both dimensions
           CALL obj%InitGravity_sboxspectral(mesh,physics,grav,iograv)
        TYPE IS (gravity_spectral)
           ! self-gravitation in flat geometries periodic in both dimensions
           CALL obj%InitGravity_spectral(mesh,physics,grav,iograv)
        END SELECT
        IF(ASSOCIATED(iograv)) CALL setattr(io, getkey(dir), iograv)
      END IF
      dir => getnext(dir)
    END DO
  END SUBROUTINE new_gravity

  SUBROUTINE closegravity()
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    ! add new source term to beginning of
    ! list of source terms
  END SUBROUTINE closegravity

END MODULE gravity_generic_mod