reconstruction_base.f90

Go to the documentation of this file.

!############################################################################
!#                                                                           #
!# fosite - 3D hydrodynamical simulation program                             #
!# module: reconstruction_base.f90                                           #
!#                                                                           #
!# Copyright (C) 2007-2012                                                   #
!# Tobias Illenseer <tillense@astrophysik.uni-kiel.de>                       #
!# Jannes Klee      <jklee@astrophysik.uni-kiel.de>                          #
!#                                                                           #
!# This program is free software; you can redistribute it and/or modify      #
!# it under the terms of the GNU General Public License as published by      #
!# the Free Software Foundation; either version 2 of the License, or (at     #
!# your option) any later version.                                           #
!#                                                                           #
!# This program is distributed in the hope that it will be useful, but       #
!# WITHOUT ANY WARRANTY; without even the implied warranty of                #
!# MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or        #
!# NON INFRINGEMENT.  See the GNU General Public License for more            #
!# details.                                                                  #
!#                                                                           #
!# You should have received a copy of the GNU General Public License         #
!# along with this program; if not, write to the Free Software               #
!# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.                 #
!#                                                                           #
!#############################################################################

!----------------------------------------------------------------------------!
!----------------------------------------------------------------------------!
MODULE reconstruction_base_mod
  USE logging_base_mod
  USE mesh_base_mod
  USE marray_compound_mod
  USE physics_base_mod
  USE common_dict
  IMPLICIT NONE
  !--------------------------------------------------------------------------!
  PRIVATE
  TYPE, ABSTRACT, EXTENDS (logging_base)   ::  reconstruction_base
     CLASS(logging_base), ALLOCATABLE      :: limiter
     LOGICAL                               :: primcons
     REAL                                  :: limiter_param
  CONTAINS
    PROCEDURE                              :: initreconstruction
    procedure(calculatestates), DEFERRED  :: calculatestates
    PROCEDURE                              :: primrecon
    PROCEDURE                              :: finalize_base
    procedure(finalize), DEFERRED         :: finalize
  END TYPE reconstruction_base

  abstract INTERFACE
    PURE SUBROUTINE calculatestates(this,Mesh,Physics,rvar,rstates)
      IMPORT reconstruction_base, mesh_base, physics_base, marray_compound
      IMPLICIT NONE
      CLASS(reconstruction_base), INTENT(INOUT)   :: this
      CLASS(mesh_base),           INTENT(IN)      :: mesh
      CLASS(physics_base),        INTENT(IN)      :: physics
      CLASS(marray_compound),     INTENT(INOUT)   :: rvar
      CLASS(marray_compound),     INTENT(INOUT)   :: rstates
    END SUBROUTINE
    SUBROUTINE finalize(this)
      IMPORT reconstruction_base
      IMPLICIT NONE
      CLASS(reconstruction_base), INTENT(INOUT)   :: this
    END SUBROUTINE
  END INTERFACE

  !--------------------------------------------------------------------------!

  INTEGER, PARAMETER :: constant     = 1
  INTEGER, PARAMETER :: linear       = 2
  !--------------------------------------------------------------------------!
  PUBLIC ::                 &
       ! types
       reconstruction_base, &
       ! constants
       constant, linear
  !--------------------------------------------------------------------------!

CONTAINS


  SUBROUTINE initreconstruction(this,Mesh,Physics,config,IO,rtype,rname)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(reconstruction_base), INTENT(INOUT) :: this
    CLASS(mesh_base),           INTENT(IN)    :: Mesh
    CLASS(physics_base),        INTENT(IN)    :: Physics
    TYPE(Dict_TYP),             POINTER       :: config,IO
    INTEGER                                   :: rtype
    CHARACTER(LEN=32)                         :: rname
    !------------------------------------------------------------------------!
    INTEGER                                   :: variables
    CHARACTER(LEN=32)                         :: infostr
    INTEGER                                   :: order
    !------------------------------------------------------------------------!
    INTENT(IN)                                :: config,rtype,rname
    !------------------------------------------------------------------------!
    CALL this%InitLogging(rtype,rname)

    ! check initialization of Mesh and Physics
    IF (.NOT.mesh%Initialized().OR..NOT.physics%Initialized()) & ! TODO: Why should this not be seperated?
         CALL this%Error("InitFluxes","mesh and/or physics module uninitialized")

    ! set general reconstruction defaults
    CALL getattr(config, "order", order, linear)

    CALL getattr(config, "variables", variables, conservative)
    SELECT CASE(variables)
    CASE(primitive)
      this%primcons = .true.
    CASE DEFAULT
      this%primcons = .false.
    END SELECT

    ! print some information
    CALL this%Info(" RECONSTR-> order:             " // trim(this%GetName()))
    IF (primrecon(this)) THEN
       WRITE (infostr,'(A)') "primitive"
    ELSE
       WRITE (infostr,'(A)') "conservative"
    END IF
    CALL this%Info("            variables:         " // trim(infostr))

  END SUBROUTINE initreconstruction


  PURE FUNCTION primrecon(this) RESULT(pc)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(reconstruction_base), INTENT(IN) :: this
    LOGICAL                                :: pc
    !------------------------------------------------------------------------!
    pc = this%primcons
  END FUNCTION primrecon


  SUBROUTINE finalize_base(this)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(reconstruction_base), INTENT(INOUT) :: this
    !------------------------------------------------------------------------!
    IF (.NOT.this%Initialized()) &
         CALL this%Error("CloseReconstruction","not initialized")
  END SUBROUTINE finalize_base

END MODULE reconstruction_base_mod