boundary_periodic.f90

Go to the documentation of this file.

!#############################################################################
!#                                                                           #
!# fosite - 3D hydrodynamical simulation program                             #
!# module: boundary_periodic.f90                                             #
!#                                                                           #
!# Copyright (C) 2006-2014                                                   #
!# Tobias Illenseer <tillense@astrophysik.uni-kiel.de>                       #
!# Jubin Lirawi     <jlirawi@astrophysik.uni-kiel.de>                        #
!#                                                                           #
!# This program is free software; you can redistribute it and/or modify      #
!# it under the terms of the GNU General Public License as published by      #
!# the Free Software Foundation; either version 2 of the License, or (at     #
!# your option) any later version.                                           #
!#                                                                           #
!# This program is distributed in the hope that it will be useful, but       #
!# WITHOUT ANY WARRANTY; without even the implied warranty of                #
!# MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or        #
!# NON INFRINGEMENT.  See the GNU General Public License for more            #
!# details.                                                                  #
!#                                                                           #
!# You should have received a copy of the GNU General Public License         #
!# along with this program; if not, write to the Free Software               #
!# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.                 #
!#                                                                           #
!#############################################################################
 
!----------------------------------------------------------------------------!
!----------------------------------------------------------------------------!
MODULE boundary_periodic_mod
  USE boundary_base_mod
  USE marray_compound_mod
  USE mesh_base_mod
  USE physics_base_mod
  USE common_dict
  IMPLICIT NONE
  !--------------------------------------------------------------------------!
  PRIVATE
  TYPE, EXTENDS(boundary_base) :: boundary_periodic
  CONTAINS
    PROCEDURE :: initboundary_periodic
    PROCEDURE :: finalize
    PROCEDURE :: setboundarydata
  END TYPE
  CHARACTER(LEN=32), PARAMETER  :: boundcond_name = "periodic"
  !--------------------------------------------------------------------------!
  PUBLIC :: boundary_periodic
  !--------------------------------------------------------------------------!
 
CONTAINS
 
  SUBROUTINE initboundary_periodic(this,Mesh,Physics,dir,config)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(boundary_periodic), INTENT(INOUT) :: this
    CLASS(physics_base),      INTENT(IN)    :: Physics
    CLASS(mesh_base),         INTENT(IN)    :: Mesh
    TYPE(dict_typ),POINTER                  :: config
    INTEGER                                 :: dir
    !------------------------------------------------------------------------!
    INTENT(IN)                              :: dir
    !------------------------------------------------------------------------!
    CALL this%InitBoundary(mesh,physics,periodic,boundcond_name,dir,config)
  END SUBROUTINE initboundary_periodic
 
  SUBROUTINE setboundarydata(this,Mesh,Physics,time,pvar)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(boundary_periodic), INTENT(INOUT) :: this
    CLASS(mesh_base),         INTENT(IN) :: Mesh
    CLASS(physics_base),      INTENT(IN) :: Physics
    REAL,                     INTENT(IN) :: time
    CLASS(marray_compound),   INTENT(INOUT) :: pvar
    !------------------------------------------------------------------------!
    INTEGER                              :: i,j,k
    !------------------------------------------------------------------------!
    SELECT CASE(this%Direction%GetType())
    CASE(west)
!NEC$ IVDEP
       DO i=1,mesh%GINUM
         pvar%data4d(mesh%IMIN-i,:,:,:) = pvar%data4d(mesh%IMAX-i+1,:,:,:)
       END DO
    CASE(east)
!NEC$ IVDEP
       DO i=1,mesh%GINUM
         pvar%data4d(mesh%IMAX+i,:,:,:) = pvar%data4d(mesh%IMIN+i-1,:,:,:)
       END DO
    CASE(south)
!NEC$ IVDEP
       DO j=1,mesh%GJNUM
         pvar%data4d(:,mesh%JMIN-j,:,:) = pvar%data4d(:,mesh%JMAX-j+1,:,:)
       END DO
    CASE(north)
!NEC$ IVDEP
       DO j=1,mesh%GJNUM
         pvar%data4d(:,mesh%JMAX+j,:,:) = pvar%data4d(:,mesh%JMIN+j-1,:,:)
       END DO
    CASE(bottom)
!NEC$ IVDEP
      DO k=1,mesh%GKNUM
        pvar%data4d(:,:,mesh%KMIN-k,:) = pvar%data4d(:,:,mesh%KMAX-k+1,:)
      END DO
    CASE(top)
!NEC$ IVDEP
      DO k=1,mesh%GKNUM
        pvar%data4d(:,:,mesh%KMAX+k,:) = pvar%data4d(:,:,mesh%KMIN+k-1,:)
      END DO
    END SELECT
  END SUBROUTINE setboundarydata
 
 
  SUBROUTINE finalize(this)
    IMPLICIT NONE
    !------------------------------------------------------------------------!
    CLASS(boundary_periodic), INTENT(INOUT) :: this
    !------------------------------------------------------------------------!
    CALL this%Finalize_base()
  END SUBROUTINE finalize
 
 
END MODULE boundary_periodic_mod